田中 宏明さん:

こんにちは。

辞書の取り扱いは慣れないとややこしいですね。
と書きつつ、僕自身も別に慣れきっているわけではなく(そもそもエクセルVBAでは滅多に必要としない）、必要に迫られると過去に自分が実務で書いたコードや教材用のサンプルコードを参照しています (^^;

受講生 さん:

これは興味深い質問ですね。
ありがとうございます (^^*

Item, Items, Keys, と、いろいろ出てきてややこしいですね。

ということで、整理のために、以下のようなサンプルコードを書きました。

Microsoft Scripting Runtimeを参照のうえ、以下のコードをステップイン実行してみてください。
そうすれば理解が進むのでは？と思います。

もちろん、実行してみて不明なことがあればまた遠慮なく質問してください (^^*

'ポイント:
'[A] dic.item(文字列) -> xxx というキーで格納された値を取得する
'[B] dic.items(数値)  -> キーと値のペアのうち、 xxx 番目のものの、値を取得する
'[C] dic.keys(数値)   -> キーと値のペアのうち、 xxx 番目のものの、キーを取得する

'[OK] 以下は正常な処理の例です。 item, items という言葉の使い分けに特に注目してください。
Sub MyDicSample1_OK()
    Dim dic As New Scripting.Dictionary
    
    dic.Add "key_a", 100
    dic.Add "key_b", 200
    dic.Add "key_c", 300
    
    '[A] 以下では、キーを使って値を取得します。
    Debug.Print vbNewLine & "Get values by key"
    Debug.Print dic.Item("key_a")
    Debug.Print dic.Item("key_b")
    Debug.Print dic.Item("key_c")
    
    '[B] 以下では、インデックスを使って値を取得します。
    Debug.Print vbNewLine & "Get values by index"
    Debug.Print dic.Items(0)
    Debug.Print dic.Items(1)
    Debug.Print dic.Items(2)
    
    '[C] 以下では、インデックスを使ってキーを取得します。
    Debug.Print vbNewLine & "Get keys by index"
    Debug.Print dic.Keys(0)
    Debug.Print dic.Keys(1)
    Debug.Print dic.Keys(2)
    
    '[B], [C] を For Next 構文で書いてみました
    Dim c As Long
    Debug.Print vbNewLine & "Get items - using for structure"
    For c = 0 To dic.Count - 1
        Debug.Print dic.Items(c)
    Next

    Debug.Print vbNewLine & "Get keys - using for structure"
    For c = 0 To dic.Count - 1
        Debug.Print dic.Keys(c)
    Next
End Sub

'[NG] 以下は実行時エラーになります。Items, Keys, Item はありですが、 Key というのはNGなので。
Sub MyDicSample2_NG()
    Dim dic As New Scripting.Dictionary
    
    dic.Add "key_a", 100
    dic.Add "key_b", 200
    dic.Add "key_c", 300
    
    '[OK] 以下では、キーを使って値を取得します。
    '[A], [B], [C]のどれか？というと、[A]の構文ですね。
    Debug.Print vbNewLine & "Get values by key"
    Debug.Print dic.Item("key_a")
    Debug.Print dic.Item("key_b")
    Debug.Print dic.Item("key_c")
    
    '[NG] 以下は、構文エラーです。Items, Keys, Item はありですが、 Key というのはNG。
    '[A], [B], [C]のどれか？というと、どれでもない。
    Debug.Print vbNewLine & "Get values by key"
    Debug.Print dic.Key("key_a")
    Debug.Print dic.Key("key_b")
    Debug.Print dic.Key("key_c")
End Sub

'[NG] 以下は論理エラーになります。
'インデックスやキーの指定で文字列型の場合、数値型の場合を混在させているので紛らわしいですが、
'発展編2講座ですので、そこはサラッと流します。
'理解できない場合はさらに質問してください。
Sub MyDicSample3_NG()
    Dim dic As New Scripting.Dictionary
    
    dic.Add "key_a", 100
    dic.Add "key_b", 200
    dic.Add "key_c", 300

    '以下は、該当するキーが存在しないので、出力結果はEmpty型になります。
    '[A], [B], [C]のどれか？というと、[A]の構文ですね。
    Debug.Print vbNewLine & "Erros - keys not exists"
    Debug.Print dic.Item("0")
    Debug.Print dic.Item("1")
    Debug.Print dic.Item("2")
    
    '以下も、該当するキーが存在しないので、出力結果はEmpty型になります。
    '[A], [B], [C]のどれか？というと、[A]の構文ですね。
    Debug.Print vbNewLine & "Erros - keys not exists"
    Debug.Print dic.Item(0)
    Debug.Print dic.Item(1)
    Debug.Print dic.Item(2)

    '以下は、該当するインデックスが存在するので、それぞれに該当する item が出力されます。
    '[A], [B], [C]のどれか？というと、[B]の構文ですね。
    Debug.Print vbNewLine & "Erros - keys not exists"
    Debug.Print dic.Items("0")
    Debug.Print dic.Items("1")
    Debug.Print dic.Items("2")
    
    '以下も、該当するインデックスが存在するので、それぞれに該当する item が出力されます。
    '[A], [B], [C]のどれか？というと、[B]の構文ですね。
    Debug.Print vbNewLine & "Erros - keys not exists"
    Debug.Print dic.Items(0)
    Debug.Print dic.Items(1)
    Debug.Print dic.Items(2)
End Sub

> モジュール2では、
> For c = 0 To dic.Count - 1
> Debug.Print dic.Keys(c), dic.Items(c)　’←★
> Next
> ★「items」と複数形でしたが
> モジュール3では、
> dic.Add "sp1", dic.Item("ws1").Shapes(2)
> dic.Item("sp1").Select　’←★★
> Debug.Print dic.Item("sp1").Width
> Debug.Print dic.Item("sp1").Height
> ★★のように「item」という単数形をとるのはどうしてですか。